nmlinux/flake.nix at main · thongor77/nmlinux · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
{
  description = "NMLinux — Network Manager GUI for Linux";

  inputs = {
    nixpkgs.url     = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs   = nixpkgs.legacyPackages.${system};
        python = pkgs.python3;

        systemTools = with pkgs; [
          networkmanager   # nmcli
          iproute2         # ip
          iputils          # ping
          nmap
          whois
          net-snmp         # snmpwalk / snmpget
          bind             # dig
          traceroute
          mtr
          curl
          freerdp3         # RDP module (xfreerdp3)
          tigervnc         # VNC module (vncviewer)
          avahi            # Topology — mDNS device detection
          kdePackages.breeze-icons
          hicolor-icon-theme
        ];

        nmlinux = python.pkgs.buildPythonApplication {
          pname   = "nmlinux";
          version = "1.5.0";
          src     = ./.;
          format  = "pyproject";

          nativeBuildInputs = with python.pkgs; [ hatchling ];

          propagatedBuildInputs = with python.pkgs; [
            pyside6
            ptyprocess
            pyte
            tftpy
          ];

          makeWrapperArgs = [
            "--prefix PATH : ${pkgs.lib.makeBinPath systemTools}"
            "--prefix XDG_DATA_DIRS : ${pkgs.kdePackages.breeze-icons}/share"
            "--prefix XDG_DATA_DIRS : ${pkgs.hicolor-icon-theme}/share"
            "--set-default QT_QPA_PLATFORMTHEME kde"
            "--set NMLINUX_ICON_PATH ${pkgs.kdePackages.breeze-icons}/share"
            "--prefix QT_PLUGIN_PATH : ${pkgs.qt6.qtsvg}/lib/qt-6/plugins"
          ];

          meta = {
            description = "A free Linux adaptation of NETworkManager";
            homepage    = "https://github.com/thongor77/nmlinux";
            license     = pkgs.lib.licenses.gpl2Only;
            platforms   = pkgs.lib.platforms.linux;
          };
        };
      in {
        packages.default = nmlinux;

        apps.default = {
          type    = "app";
          program = "${nmlinux}/bin/nmlinux";
        };

        devShells.default = pkgs.mkShell {
          buildInputs = [
            (python.withPackages (ps: with ps; [
              pyside6
              ptyprocess
              pyte
              tftpy
            ]))
          ] ++ systemTools;
        };
      }
    );
}